3.1. Wat is de arbeidsintensiteit PIL & PNIL?

Concepten

• Grootboekpost
• Grootboekrubriek

Relaties

• deel van
• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 3.1
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
6PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
7PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
8
9SELECT ?Kental (?Waarde AS ?Arbeidsintensiteit)
10WHERE {
11  {
12    SELECT
13      (
14        IF(
15          BOUND(?p_totaal) && (?p_totaal != 0),
16          (xsd:decimal(?q_bedragen) / xsd:decimal(?p_totaal)),
17          "Ongedefinieerd"
18        ) AS ?aipnilpil
19      )
20    WHERE {
21      {
22        SELECT ((COALESCE(?p_prismant,0) + COALESCE(?p_rgs,0)) AS ?p_totaal) ((COALESCE(?q_prismant,0) + COALESCE(?q_rgs,0)) AS ?q_bedragen)
23        WHERE {
24
25          {
26            SELECT
27              (SUM(?p_bedrag_prismant) AS ?p_prismant)
28              (SUM(?q_bedrag_prismant) AS ?q_prismant)
29            WHERE {
30              #BIND(2024 AS ?jaar)
31              BIND(STRDT(CONCAT(STR(?jaar),"-01-01"),xsd:date) AS ?startperiode)
32              BIND(STRDT(CONCAT(STR(?jaar),"-12-31"),xsd:date) AS ?eindperiode)
33
34              {
35                SELECT DISTINCT ?rubriek WHERE {
36                  ?rubriek a onz-fin:Grootboekrubriek .
37                  FILTER(STRSTARTS(STR(?rubriek), STR(onz-fin:)))
38                  FILTER(REGEX(STRAFTER(STR(?rubriek), STR(onz-fin:)), "^[0-9]{6}$"))
39                }
40              }
41
42              BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
43
44              ?grootboek_post a onz-fin:Grootboekpost ;
45                              onz-g:partOf ?rubriek ;
46                              onz-g:hasDate ?datum ;
47                              onz-fin:heeftGeldBedrag ?geld_bedrag .
48
49              FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
50
51              BIND(
52                IF(
53                  STRSTARTS(?rubriekCode, "8") ||
54                  STRSTARTS(?rubriekCode, "919") ||
55                  STRSTARTS(?rubriekCode, "920") ||
56                  STRSTARTS(?rubriekCode, "930"),
57                  ?geld_bedrag, 0
58                ) AS ?p_bedrag_prismant
59              )
60
61              BIND(
62                IF(
63                  STRSTARTS(?rubriekCode, "41")  ||
64                  STRSTARTS(?rubriekCode, "420") ||
65                  STRSTARTS(?rubriekCode, "422"),
66                  ?geld_bedrag, 0
67                ) AS ?q_bedrag_prismant
68              )
69            }
70          }
71
72          {
73            SELECT
74              (SUM(?p_bedrag_rgs) AS ?p_rgs)
75              (SUM(?q_bedrag_rgs) AS ?q_rgs)
76            WHERE {
77              #BIND(2024 AS ?jaar)
78              BIND(STRDT(CONCAT(STR(?jaar),"-01-01"),xsd:date) AS ?startperiode)
79              BIND(STRDT(CONCAT(STR(?jaar),"-12-31"),xsd:date) AS ?eindperiode)
80
81              VALUES (?rubriek ?soort) {
82                (onz-fin:WOmz "P")
83                (onz-fin:WRev "P")
84                (onz-fin:WRvi "P")
85                (onz-fin:WRgr "P")
86                (onz-fin:WWvv "P")
87                (onz-fin:WNoa "P")
88                (onz-fin:WLbe "P")
89                (onz-fin:WBat "P")
90                (onz-fin:WWiv "P")
91                (onz-fin:WOvb "P")
92                (onz-fin:WKprKuw      "Q")
93                (onz-fin:WKprKvp      "Q")
94                (onz-fin:WPer         "Q")
95                (onz-fin:WBedOvpUik   "Q")
96                (onz-fin:WBedOvpUit   "Q")
97                (onz-fin:WBedOvpMaf   "Q")
98                (onz-fin:WBedOvpZzp   "Q")
99                (onz-fin:WBedOvpPay   "Q")
100                (onz-fin:WBedOvpOip   "Q")
101              }
102
103              ?grootboek_post a onz-fin:Grootboekpost ;
104                              onz-g:partOf* ?rubriek ;
105                              onz-g:hasDate ?datum ;
106                              onz-fin:heeftGeldBedrag ?geld_bedrag .
107
108              FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
109
110              BIND(IF(?soort = "P", ?geld_bedrag, 0) AS ?p_bedrag_rgs)
111              BIND(IF(?soort = "Q", ?geld_bedrag, 0) AS ?q_bedrag_rgs)
112            }
113          }
114        }
115      }
116    }
117  }
118
119  VALUES ?Kental {
120    "Arbeidsintensiteit PIL & PNIL"
121    "Arbeidsintensiteit PIL & PNIL (%)"
122  }
123
124  BIND(
125    IF(
126      DATATYPE(?aipnilpil) = xsd:string,
127      "Ongedefinieerd"^^xsd:string,
128      IF(
129        ?Kental = "Arbeidsintensiteit PIL & PNIL",
130        ROUND(?aipnilpil * 100) / 100,
131        ROUND((?aipnilpil * 100) * 100) / 100
132      )
133    ) AS ?Waarde
134  )
135}
136ORDER BY ?Kental
137